উইকিপিডিয়া

চিত্র:QuantumHarmonicOscillatorAnimation.gif

QuantumHarmonicOscillatorAnimation.gif ‎(৩০০ × ৩৭৩ পিক্সেল, ফাইলের আকার: ৭৫৯ কিলোবাইট, এমআইএমই ধরন: image/gif, লুপকৃত, ৯৭ ফ্রেম)

এই ফাইলটি উইকিমিডিয়া কমন্স থেকে নেওয়া। সেখানের বর্ণনা পাতার বিস্তারিত নিম্নে দেখানো হলো। (সম্পাদনা)
উইকিমিডিয়া কমন্স, মুক্ত লাইসেন্সযুক্ত মিডিয়ার একটি ভান্ডার। আপনি সাহায্য করতে পারেন।

সারাংশ

বিবরণ
English: A harmonic oscillator in classical mechanics (A-B) and quantum mechanics (C-H). In (A-B), a ball, attached to a spring (gray line), oscillates back and forth. In (C-H), wavefunction solutions to the Time-Dependent Schrödinger Equation are shown for the same potential. The horizontal axis is position, the vertical axis is the real part (blue) or imaginary part (red) of the wavefunction. (C,D,E,F) are stationary states (energy eigenstates), which come from solutions to the Time-Independent Schrodinger Equation. (G-H) are non-stationary states, solutions to the Time-Dependent but not Time-Independent Schrödinger Equation. (G) is a randomly-generated superposition of the four states (E-F). H is a "coherent state" ("Glauber state") which somewhat resembles the classical state B.
العربية: مذبذب توافقي في الميكانيكا الكلاسيكية (A-B) وميكانيكا الكم (C-H). في (A-B)، كرة متصلة بنابض (خط رمادي)، تتأرجح ذهابًا وإيابًا. في (C-H)، يعرض حلول الدالة الموجية لمعادلة شرودنغر المعتمدة على الوقت لنفس الإمكانات. المحور الأفقي هو الموضع، والمحور العمودي هو الجزء الحقيقي (الأزرق) أو الجزء التخيلي (الأحمر) من دالة الموجة. (C ،D ،E ،F) هي حالات ثابتة (حالات الطاقة الذاتية)، والتي تأتي من حلول معادلة شرودنغر المستقلة عن الزمن. (G-H) هي حالات غير ثابتة، وهي حلول لمعادلة شرودنغر التي تعتمد على الوقت ولكنها ليست مستقلة عن الوقت. (G) هو تراكب أنشىء عشوائيًا للحالات الأربع (E-F). H هي "حالة متماسكة" ("حالة جلوبر") تشبه إلى حد ما الحالة الكلاسيكية B.
তারিখ
উৎস নিজের কাজ
লেখক Sbyrnes321 
(* Source code written in Mathematica 6.0 by Steve Byrnes, Feb. 2011. This source code is public domain. *)
(* Shows classical and quantum trajectory animations for a harmonic potential. Assume m=w=hbar=1. *)
ClearAll["Global`*"]
(*** Wavefunctions of the energy eigenstates ***)
psi[n_, x_] := (2^n*n!)^(-1/2)*Pi^(-1/4)*Exp[-x^2/2]*HermiteH[n, x];
energy[n_] := n + 1/2;
psit[n_, x_, t_] := psi[n, x] Exp[-I*energy[n]*t];
(*** A random time-dependent state ***)
SeedRandom[1];
CoefList = Table[Random[]*Exp[2 Pi I Random[]], {n, 0, 4}];
CoefList = CoefList/Norm[CoefList];
Randpsi[x_, t_] := Sum[CoefList[[n + 1]]*psit[n, x, t], {n, 0, 4}];
(*** A coherent state (or "Glauber state") ***)
CoherentState[b_, x_, t_] := Exp[-Abs[b]^2/2] Sum[b^n*(n!)^(-1/2)*psit[n, x, t], {n, 0, 15}];
(*** Make the classical plots...a red ball anchored to the origin by a gray spring. ***)
classical1[t_, max_] := ListPlot[{{max Cos[t], 0}}, PlotStyle -> Directive[Red, AbsolutePointSize[15]]];
zigzag[x_] := Abs[(x + 0.25) - Round[x + 0.25]] - .25;
spring[x_, left_, right_] := (.9 zigzag[3 (x - left)/(right - left)])/(1 + Abs[right - left]);
classical2[t_, max_] := Plot[spring[x, -5, max Cos[t]], {x, -5, max Cos[t]}, PlotStyle -> Directive[Gray, Thick]];
classical3 = ListPlot[{{-5, 0}}, PlotStyle -> Directive[Black, AbsolutePointSize[7]]];
classical[t_, max_, label_] := Show[classical2[t, max], classical1[t, max], classical3, 
   PlotRange -> {{-5, 5}, {-1, 1}}, Ticks -> None, Axes -> {False, True}, PlotLabel -> label, AxesOrigin -> {0, 0}];
(*** Put all the plots together ***)
SetOptions[Plot, {PlotRange -> {-1, 1}, Ticks -> None, PlotStyle -> {Directive[Thick, Blue], Directive[Thick, Pink]}}];
MakeFrame[t_] := GraphicsGrid[
   {{classical[t + 2, 1.5, "A"], classical[t, 3, "B"]},
    {Plot[{Re[psit[0, x, t]], Im[psit[0, x, t]]}, {x, -5, 5}, PlotLabel -> "C"], 
     Plot[{Re[psit[1, x, t]], Im[psit[1, x, t]]}, {x, -5, 5}, PlotLabel -> "D"]},
    {Plot[{Re[psit[2, x, t]], Im[psit[2, x, t]]}, {x, -5, 5}, PlotLabel -> "E"], 
     Plot[{Re[psit[3, x, t]], Im[psit[3, x, t]]}, {x, -5, 5}, PlotLabel -> "F"]},
    {Plot[{Re[Randpsi[x, t]], Im[Randpsi[x, t]]}, {x, -5, 5}, PlotLabel -> "G"], 
     Plot[{Re[CoherentState[1, x, t]], Im[CoherentState[1, x, t]]}, {x, -5, 5}, PlotLabel -> "H"]}
    }, Frame -> All, ImageSize -> 300];
output = Table[MakeFrame[t], {t, 0, 4 Pi*96/97, 4 Pi/97}];
SetDirectory["C:\\Users\\Steve\\Desktop"]
Export["test.gif", output]

লাইসেন্স প্রদান

আমি, এই কাজের স্বত্বাধিকারী, এতদ্দ্বারা আমি এই কাজকে নিম্ন বর্ণিত লাইসেন্সের আওতায় প্রকাশ করলাম:
Creative Commons CC-Zero এই ফাইলটি ক্রিয়েটিভ কমন্স সিসি০ ১.০ সার্বজনীন পাবলিক ডোমেইন উৎসর্গীকরণের আওতায় রয়েছে।
যেই ব্যক্তিটি এই কাজটির সাথে সংশ্লিষ্ট তিনি এই কাজটি পাবলিক ডোমেইনে মুক্ত করার মাধ্যমে তাঁর সকল স্বত্ত্ব বিশ্বের সকল কপিরাইট আইনের আওতায় ত্যাগ করেছেন। যার মধ্যে নেইবারিং অধিকার, ও আইনের মাধ্যমে এক্সটেন্টও অন্তর্গত। আপনি এই কাজটি কোন অনুমতি চাওয়া ছাড়াই মুক্তভাবে অনুলিপি, পরিবর্তন, বিতরণ করতে পারেন, এবং এমন কি কোনো বাণিজ্যিক কাজেও ব্যবহার করতে পারেন।

ক্যাপশন

এই ফাইল কি প্রতিনিধিত্ব করছে তার এক লাইন ব্যাখ্যা যোগ করুন

এই ফাইলে চিত্রিত আইটেমগুলি

যা চিত্রিত করে

ফাইলের ইতিহাস

যেকোনো তারিখ/সময়ে ক্লিক করে দেখুন ফাইলটি তখন কী অবস্থায় ছিল।

তারিখ/সময়সংক্ষেপচিত্রমাত্রাব্যবহারকারীমন্তব্য
বর্তমান০৯:১৬, ২ মার্চ ২০১১০৯:১৬, ২ মার্চ ২০১১-এর সংস্করণের সংক্ষেপচিত্র৩০০ × ৩৭৩ (৭৫৯ কিলোবাইট)Sbyrnes321Alter spring, to avoid the visual impression that the ball is rotating in a circle around the y-axis through the third dimension.
২২:৫৫, ১ মার্চ ২০১১২২:৫৫, ১ মার্চ ২০১১-এর সংস্করণের সংক্ষেপচিত্র৩০০ × ৩৭৩ (৭৩৩ কিলোবাইট)Sbyrnes321Add zigzag spring; shrink image to 300px width; increase frame count to 97.
২৩:৫৮, ২৭ ফেব্রুয়ারি ২০১১২৩:৫৮, ২৭ ফেব্রুয়ারি ২০১১-এর সংস্করণের সংক্ষেপচিত্র৩৪৭ × ৪৩২ (৭০৭ কিলোবাইট)Sbyrnes321Switched from 100 frames to 80 frames, to be under the 12.5-million-pixel limit for animations in wikipedia articles.
২৩:০৬, ২৭ ফেব্রুয়ারি ২০১১২৩:০৬, ২৭ ফেব্রুয়ারি ২০১১-এর সংস্করণের সংক্ষেপচিত্র৩৪৭ × ৪৩২ (৮৮৭ কিলোবাইট)Sbyrnes321{{Information |Description ={{en|1=A harmonic oscillator in classical mechanics (A-B) and quantum mechanics (C-H). In (A-B), a ball, attached to a spring (gray line), oscillates back and forth. In (C-H), wavefunction solutions to the Time-Dependent Sch

নিচের পৃষ্ঠা(গুলো) থেকে এই ছবিতে সংযোগ আছে:

ফাইলের বৈশ্বিক ব্যবহার

নিচের অন্যান্য উইকিগুলো এই ফাইলটি ব্যবহার করে:

এই ফাইলের অন্যান্য বৈশ্বিক ব্যবহার দেখুন।

'https://bn.wikipedia.org/wiki/চিত্র:QuantumHarmonicOscillatorAnimation.gif' থেকে আনীত